Schema​

Required vs optional​

Properties are optional by default. Use the required keyword to make them required.

type Movie {
  required title: str;       # required
  release_year: int64;       # optional
}

See Schema > Properties.

Constraints​

Add a pair of curly braces after the property to define additional information, including constraints.

type Movie {
  required title: str {
    constraint exclusive;
    constraint min_len_value(8);
    constraint regexp(r'^[A-Za-z0-9 ]+$');
  }
}

See Schema > Constraints.

Computed properties​

Object types can contain computed properties that correspond to EdgeQL expressions. This expression is dynamically computed whenever the property is queried.

type Movie {
  required title: str;
  uppercase_title := str_upper(.title);
}

See Schema > Computeds.

Computed links​

Objects can contain “computed links”: stored expressions that return a set of objects. Computed links are dynamically computed when they are referenced in queries. The example below defines a backlink.

type Movie {
  required title: str;
  multi actors: Person;

  # returns all movies with same title
  multi same_title := (
    with t := .title
    select detached Movie filter .title = t
  )
}

Backlinks​

A common use case for computed links is backlinks.

type Movie {
  required title: str;
  multi actors: Person;
}

type Person {
  required name: str;
  multi acted_in := .<actors[is Movie];
}

The computed link acted_in returns all Movie objects with a link called actors that points to the current Person. The easiest way to understand backlink syntax is to split it into two parts:

.<actors

This uses a special syntax .< to return all objects in the database with a link called actors that points to the current object. This set could conceivably contain other objects besides Movie; for instance, we could define a TVShow type that also included link actors -> Person.

[is Movie]

This is a type filter that filters out all objects that aren’t Movie objects. A backlink still works without this filter, but could contain any other number of objects besides Movie objects.

See Schema > Computeds > Backlinks.