Shapes

Subtopics

Sometimes it is not enough to fetch the data as is, but it is necessary to add something extra to it. This can be done by adding a computed field to the shape. Let's fetch all the accounts and add the username length as well as the length of their watchlist to the results:

Input

Run

select Account {
  username,
  # Computed value for the number of characters in
  # the username.
  len_username := len(.username),
  # Use count for figuring out the length of the watchlist.
  len_watchlist := count(.watchlist)
};

select Account {
  username,
  # Computed value for the number of characters in
  # the username.
  len_username := len(.username),
  # Use count for figuring out the length of the watchlist.
  len_watchlist := count(.watchlist)
};

Output Objects

Press the 'Run' button to evaluate the input

We can even incorporate a comparison to the average username length in our computed field. There are several ways to do this, but in this example we'll use the detached keyword. Using detached denotes that the Account that we're referring to in the subquery is the original unmodified set in the database rather than the object for which we're computing the value of above_avg:

Input

Run

select Account {
  username,
  len_username := len(.username),
  # Try this with and without detached to see the difference.
  above_avg :=
    len(.username) > math::mean(len(detached Account.username))
};

select Account {
  username,
  len_username := len(.username),
  # Try this with and without detached to see the difference.
  above_avg :=
    len(.username) > math::mean(len(detached Account.username))
};

Output Objects

Press the 'Run' button to evaluate the input

On the next page, we'll learn to use a with block to do the same query in a more readable way.

Prev Next